sqlserver之触发器
触发器是一个在修改指定表中数据时执行的储存过程。它是一种特殊的存储过程﹐它不能被显式地调用，而是在往表中插入记录﹑更新记录或者删除记录时被自动地激活。而储存过程可以通过其名字被直接调用。一、触发器作用：自动执行，他们在表的数据做了任何修改之后立即激活。
可以实现复杂的数据库更新操作，可以调用一个或多个存储过程，甚至外部过程完成相应的操作。
可以实现比check约束更为复杂的数据完整性约束，可以引用其他表的列。
可以检测数据库内的操作，从而取消未经许可的更新操作，使数据库更新更安全。
能够对数据库的相关表进行级联更改。
二、种类：
[*]DDL（数据定义语言 Data Definition Language）：针对数据库级别的，用于在数据库中执行管理任务。DDL事件即指在表或索引中的create、alter、drop语句。
[*]DML（ 数据操纵语言 Data Manipulation Language）：DML事件即指在表或视图中修改数据的insert、update、delete语句。
[*]登录触发器：是指当用户登录SQL SERVER实例建立会话时触发。在登陆验证完成之后且用户会话实际建立之前激发。可以用来审核和控制服务器会话，如：跟踪登录活动、限制登录名和限制登录名的会话数。
三、触发方式：
[*] AFTER触发器：它是在执行INSERT、UPDATE、DELETE语句操作之后执行触发器操作。它主要是用于记录变更后的处理或检查，一旦发生错误，可以回滚本次操作，但不能对视图定义AFTER触发器。
[*]INSTEAD OF触发器：它在执行INSERT、UPDATE、DELETE语句操作之前执行触发器本身所定义的操作，并不执行引起触发的操作（insert、update、delete）。而INSTEAD OF触发器是可以定义在视 图上的。
四、触发器有两个特殊的表：
插入表（instered表）和删除表（deleted表）。这两张是逻辑表也是虚表。是在内存中创建的，不会存储在数据库中，而且都是只读的。这两张表的结果总是与被改触发器应用的表的结构相同。当触发器完成工作后，这两张表就会被删除。Inserted表的数据：即新的记录，是插入或是修改后的数据；deleted表的数据：即旧的记录，是更新前的或是删除的数据。
一个Update 的过程可以看作为：生成新的记录到Inserted表，复制旧的记录到Deleted表。
触发器操作代码
一创建触发器语法
create trigger tgr_name
on table_name
with encrypion –加密触发器
for update...
as
Transact-SQL
二创建insert类型触发器
if (object_id('tgr_classes_insert', 'tr') is not null)
drop trigger tgr_classes_insert
go
create trigger tgr_classes_insert
on classes
for insert --插入触发
as
--定义变量
declare @id int, @name varchar(20), @temp int;
--在inserted表中查询已经插入记录信息
select @id = id, @name = name from inserted;
set @name = @name + convert(varchar, @id);
set @temp = @id / 2;
insert into student values(@name, 18 + @id, @temp, @id);
print '添加学生成功！';
go
--插入数据
insert into classes values('5班', getDate());
--查询数据
select * from classes;
select * from student order by id;
三创建delete类型触发器
if (object_id('tgr_classes_delete', 'TR') is not null)
drop trigger tgr_classes_delete
go
create trigger tgr_classes_delete
on classes
for delete --删除触发
as
print '备份数据中……';
if (object_id('classesBackup', 'U') is not null)
--存在classesBackup，直接插入数据
insert into classesBackup select name, createDate from deleted;
else
--不存在classesBackup创建再插入
select * into classesBackup from deleted;
print '备份数据成功！';
go
--
--不显示影响行数
--set nocount on;
delete classes where name = '5班';
--查询数据
select * from classes;
select * from classesBackup;
delete触发器会在删除数据的时候，将刚才删除的数据保存在deleted表中。
四 创建update类型触发器
--update更新类型触发器
if (object_id('tgr_classes_update', 'TR') is not null)
drop trigger tgr_classes_update
go
create trigger tgr_classes_update
on classes
for update
as
declare @oldName varchar(20), @newName varchar(20);
--更新前的数据
select @oldName = name from deleted;
if (exists (select * from student where name like '%'+ @oldName + '%'))
begin
--更新后的数据
select @newName = name from inserted;
update student set name = replace(name, @oldName, @newName) where name like '%'+ @oldName + '%';
print '级联修改数据成功！';
end
else
print '无需修改student表！';
go
--查询数据
select * from student order by id;
select * from classes;
update classes set name = '五班' where name = '5班';
update触发器会在更新数据后，将更新前的数据保存在deleted表中，更新后的数据保存在inserted表中。
五update更新列级触发器
if (object_id('tgr_classes_update_column', 'TR') is not null)
drop trigger tgr_classes_update_column
go
create trigger tgr_classes_update_column
on classes
for update
as
--列级触发器：是否更新了班级创建时间
if (update(createDate))
begin
raisError('系统提示：班级创建时间不能修改！', 16, 11);
rollback tran;
end
go
--测试
select * from student order by id;
select * from classes;
update classes set createDate = getDate() where id = 3;
update classes set name = '四班' where id = 7;
更新列级触发器可以用update是否判断更新列记录；
六 instead of类型触发器
instead of触发器表示并不执行其定义的操作（insert、update、delete）而仅是执行触发器本身的内容。
创建语法
create trigger tgr_name
on table_name
with encryption
instead of update...
as
T-SQL
# 创建instead of触发器
if (object_id('tgr_classes_inteadOf', 'TR') is not null)
drop trigger tgr_classes_inteadOf
go
create trigger tgr_classes_inteadOf
on classes
instead of delete/*, update, insert*/
as
declare @id int, @name varchar(20);
--查询被删除的信息，并赋值
select @id = id, @name = name from deleted;
print 'id: ' + convert(varchar, @id) + ', name: ' + @name;
--先删除student的信息
delete student where cid = @id;
--再删除classes的信息
delete classes where id = @id;
print '删除[ id: ' + convert(varchar, @id) + ', name: ' + @name + ' ] 的信息成功！';
go
--test
select * from student order by id;
select * from classes;
delete classes where id = 7;
七显示自定义消息raiserror
if (object_id('tgr_message', 'TR') is not null)
drop trigger tgr_message
go
create trigger tgr_message
on student
after insert, update
as raisError('tgr_message触发器被触发', 16, 10);
go
--test
insert into student values('lily', 22, 1, 7);
update student set sex = 0 where name = 'lucy';
select * from student order by id;
八修改触发器
alter trigger tgr_message
on student
after delete
as raisError('tgr_message触发器被触发', 16, 10);
go
--test
delete from student where name = 'lucy';
九启用、禁用触发器
--禁用触发器
disable trigger tgr_message on student;
--启用触发器
enable trigger tgr_message on student;
十查询创建的触发器信息
--查询已存在的触发器
select * from sys.triggers;
select * from sys.objects where type = 'TR';
--查看触发器触发事件
select te.* from sys.trigger_events te join sys.triggers t
on t.object_id = te.object_id
where t.parent_class = 0 and t.name = 'tgr_valid_data';
--查看创建触发器语句
exec sp_helptext 'tgr_message';
十一示例
# 示例，验证插入数据
if ((object_id('tgr_valid_data', 'TR') is not null))
drop trigger tgr_valid_data
go
create trigger tgr_valid_data
on student
after insert
as
declare @age int,
@name varchar(20);
select @name = s.name, @age = s.age from inserted s;
if (@age < 18)
begin
raisError('插入新数据的age有问题', 16, 1);
rollback tran;
end
go
--test
insert into student values('forest', 2, 0, 7);
insert into student values('forest', 22, 0, 7);
select * from student order by id;
# 示例，操作日志
if (object_id('log', 'U') is not null)
drop table log
go
create table log(
id int identity(1, 1) primary key,
action varchar(20),
createDate datetime default getDate()
)
go
if (exists (select * from sys.objects where name = 'tgr_student_log'))
drop trigger tgr_student_log
go
create trigger tgr_student_log
on student
after insert, update, delete
as
if ((exists (select 1 from inserted)) and (exists (select 1 from deleted)))
begin
insert into log(action) values('updated');
end
else if (exists (select 1 from inserted) and not exists (select 1 from deleted))
begin
insert into log(action) values('inserted');
end
else if (not exists (select 1 from inserted) and exists (select 1 from deleted))
begin
insert into log(action) values('deleted');
end
go
--test
insert into student values('king', 22, 1, 7);
update student set sex = 0 where name = 'king';
delete student where name = 'king';
select * from log;
select * from student order by id;
页:
[1]